100 REM TEXTHARDCOPY
110 ZS=PEEK(53272) : REM ZEICHENSATZ ERMITTELN
120 B=1024 : REM STARTADRESSE DES BILDSCHIRMS
130 D$="C" : REM DRUCKERTYP
140 :        REM "C" = COMMODORE
150 :        REM "A" = ASCII
160 IF ZS=21 THEN OPEN 1,4,0 : REM GROSS/GRAFIK
170 IF ZS=23 THEN OPEN 1,4,7 : REM KLEIN/GROSS
180 IF ZS <> 21 AND ZS <> 23 THEN END : REM KEIN NORMALER ZEICHENSATZ
190 :
200 PRINT#1,CHR$(27);"@" : REM DRUCKER INITIALISIEREN
210 PRINT#1,CHR$(27);CHR$(108);CHR$(10); : REM 10 SPALTEN LINKER RAND
220 :
230 FOR Z=0 TO 24
240 : FOR S=0 TO 39
250 :
260 :   M=B+Z*40+S
270 :   X = PEEK(M)
280 :   IF X>127 THEN X=X-128 : REM REVERSES ZEICHEN -> NORMALES ZEICHEN
290 :   IF X>=32 AND X<=63 THEN450: REM SONDERZEICHEN
300 :   IF D$="A" THEN350: REM DRUCKER-PRUEFUNG
310 :   REM COMMODORE
320 :    IF X>=64 AND X<=95 THEN X=X+32 : GOTO450
330 :    X=X+64
340 :    GOTO450
350 :   REM ASCII
360 :    IF ZS = 21 THEN420: REM ZS-PRUEFUNG
370 :     REM ZS KLEIN/GROSS
380 :      IF X<=31 THEN X=X+96 : GOTO450
390 :      IF X>=96 THEN X=32 : GOTO450: REM NICHT DRUCKBARES ZEICHEN
400 :      GOTO450
410 :     REM ZS GROSS/GRAFIK
420 :      IF X<=31 THEN X=X+64 : GOTO450
430 :      X=32 : REM NICHT DRUCKBARES ZEICHEN
440 :
450 :   PRINT#1,CHR$(X);
460 : NEXT S
470 : PRINT#1,CHR$(13);
480 NEXT Z
490 CLOSE 1